Innehåll

# Informationsfunktioner

Den här kategorin innehåller informationsfunktioner.

Så här använder du det här kommandot...

Infoga - Funktion - Kategori Information

Informationen i följande tabeller fungerar som grund för vissa exempel i funktionsbeskrivningarna:

| C | D
2 | x-värde | y-värde
3 | -5 | -3
4 | -2 | 0
5 | -1 | 1
6 | 0 | 3
7 | 2 | 4
8 | 4 | 6
9 | 6 | 8

## AKTUELL

Den här funktionen returnerar det aktuella resultatet för beräkning av den formel som är den är en del av (dvs. resultatet så långt som beräkningen utförts). Dess viktigaste användningsområde är att tillsammans med FORMAT()-funktionen använda vissa format med en cell beroende på innehållet i cellen.

#### Syntax

AKTUELL().

#### Exempel

=1+2+AKTUELL()

Exemplet returnerar 6. Formeln beräknas från vänster till höger som: 1 + 2 är lika med 3, vilket ger ett aktuellt resultat när AKTUELL() påträffas. AKTUELL() blir därför 3, vilket multipliceras med den ursprungliga trean (3) för att få 6

=A2+B2+STYLE(IF(CURRENT()>10;"Red";"Default"))

Exemplet returnerar A2 + B2 (FORMAT returnerar 0 här). Om summan är större än 10 används formatet Röd för cellen. Se funktionen FORMAT för mer information.

="tuff"&AKTUELL()

Exemplet returnerar tufftuff.

#### Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.CURRENT

## CELL

Returnerar information om en cells adress, formatering eller innehåll.

#### Syntax

CELL("InfoType" [; Reference])

Infotyp är den textsträng som anger informationstypen. Textsträngen är alltid på engelska. Versaler och gemener är valfritt.

Infotyp | Betydelse
--- | ---
COL | Returnerar numret på den refererade kolumnen. =CELL("KOL";D2) returnerar 4.
ROW | Returnerar numret på den refererade raden. =CELL("RAD";D2) returnerar 2.
SHEET | Returnerar numret på den refererade tabellen. =CELL("Tabell";Tabell3.D2) returnerar 3.
ADDRESS | Returnerar den absoluta adressen på den refererade tabellen. =CELL("ADRESS";D2) returnerar $D$2. =CELL("ADRESS";Tabell3.D2) returnerar $Sheet3.$D$2. =CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.$D$2.
FILENAME | Returnerar filnamn och tabellnamn på den refererade cellen. =CELL("FILENAME";D2) returns 'file:///X:/dr/own.ods'#$Sheet1, if the formula in the current document X:\dr\own.ods is located in Sheet1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.
COORD | Returns the complete cell address in Lotus™ notation. =CELL("KOORD"; D2) returnerar $A:$D$2. =CELL("KOORD"; Tabell3.D2) returnerar $C:$D$2.
CONTENTS | Returnerar innehållet i den refererade cellen utan någon formatering.
TYPE | Returnerar typen av cellinnehåll. b = blank. tom cell l = label. Text, resultat av en formel i form av text v = value. Värde, resultat av en formel i form av tal
WIDTH | Returnerar bredden på den refererade kolumnen. Måttenheten är antalet nollor (0) som passar i kolumnen, i standardteckensnittet med standardstorlek.
PREFIX | Returnerar justeringen på den refererade cellen. ' = vänsterjusterad eller marginaljusterad " = högerjusterad ^ = centrerad \ = upprepande (inaktiv för närvarande)
PROTECT | Returnerar status för cellens cellskydd. 1 = cell är skyddad 0 = cell är inte skyddad

FORMAT

Returnerar en sträng som anger talformatet.

, = tal med tusentalsavgränsare

F = tal utan tusentalsavgränsare

C = valutaformat

S = exponentiell framställning, t.ex. 1.234+E56

P = procenttal

I formaten ovan, returneras antalet decimaler efter decimalkommat som ett tal. Exempel: talformatet #,##0,0 returnerar 1 och talformatet 00,000% returnerar P3.

D1 = D-MMM-YY, D-MM-YY och liknande format

D2 = DD-MM

D3 = MM-YY

D4 = DD-MM-YYYY HH:MM:SS

D5 = MM-DD

D6 = HH:MM:SS AM/PM

D7 = HH:MM AM/PM

D8 = HH:MM:SS

D9 = HH:MM

G = Alla andra format

- (minus) i slutet = negativa tal formateras med färg

() (parentespar) i slutet = det förekommer en inledande parentes i formatkod

COLOR | Returnerar 1 om negativa värden är formaterade med färg, annars 0.
PARENTHESES | Returnerar 1 om det finns en öppen parentes ( i formatkoden, annars 0.

referens (valfritt) är positionen för cellen som ska undersökas. Om referens är ett område, gäller cellen uppe till vänster i området. Om referens saknas, använder LibreOffice Calc positionen för cellen där den här formeln står. Microsoft Excel använder då referensen för cellen där markören står.

## FORMEL

Visar formeln i en formelcell som en textsträng.

This function is always recalculated whenever a recalculation occurs.

#### Syntax

FORMEL(Referens)

Referens är en referens till en cell som innehåller en formel.

En ogiltig referens eller en referens till en cell utan någon formel resulterar i felvärdet #SAKNAS.

#### Exempel

Om cell A8 innehåller formeln =SUMMA(1;2;3) så

=FORMEL(A8) returnerar texten =SUMMA(1;2;3).

## INFO

Returnerar specifik information om den aktuella arbetsmiljön. Funktionen tar emot ett enskilt textargument och returnerar data utifrån den parametern.

This function is always recalculated whenever a recalculation occurs.

#### Syntax

INFO("Typ")

I följande tabell visas värden för textparametern Typ och returvärdena för INFO-funktionen.

Värde för "Typ" | Returvärde
--- | ---
"osversion" | Alltid "Windows (32-bitars) NT 5.01", för kompatibilitetens skull

"system"

The type of the operating system:
"ANDROID" for Google mobile operating system
"DRAGONFLY" for DragonFly operating system forked from FreeBSD
"EMSCRIPTEN" for browser WebAssembly system
"FREEBSD", "OPENBSD" or "NETBSD" for operating systems based on the Berkeley Software Distribution (BSD)
"HAIKU" for BeOS compatible operating system
"iOS" for Apple mobile operating system
"LINUX" for GNU/Linux based operating systems
"MACOSX" for Apple macOS
"SOLARIS" for Oracle Solaris operating system
"WNT" for Microsoft Windows

"release" | Identifierare för produktversion, t.ex. "300m25(Build:9876)"
"numfile" | Alltid 1 för kompatibilitetens skull
"recalc" | Aktuellt läge för beräkning av formel, antingen "Automatisk" eller "Manuell" (lokaliserad till LibreOffice-språk)

Andra kalkylprogram kan acceptera regionalt anpassade värden för parametern Typ, men LibreOffice Calc accepterar endast engelska värden.

#### Exempel

=INFO("version") returnerar produktens versionsnummer för LibreOffice som används.

=INFO(D5) med cell D5 som innehåller ett textsträngssystem returnerar operativsystemstypen.

## N

Returnerar ett numeriskt värde av angiven parameter. Returnerar 0 om parameter är text eller FALSK.

Om ett fel inträffar returnerar funktionen ett felvärde.

#### Syntax

N(Värde)

Värde är den parameter som ska konverteras till ett nummer. N() returnerar det numeriska värdet, om det kan. Logiska värdena SANT och FALSKT returneras som 1 och 0. Text returneras som 0.

#### Exempel

=N(123) returnerar 123

=N(SANT) returnerar 1

=N(FALSKT) returnerar 0

=N("abc") returnerar 0

=N(1/0) returnerar #DIVISION/0!

## OMFEL

Returns the value if the cell does not contain an error value, or the alternative value if it does.

This function is available since LibreOffice 4.0.

#### Syntax

IFERROR(Value; Alternate_value)

Värde är det värde eller uttryck som ska returneras om det inte är lika med eller resulterar i ett fel.

Alternativt_värde är det värde eller uttryck som ska returneras om uttrycket eller värdet från Värde är lika med eller resulterar i ett fel.

#### Exempel

=OMFEL(C8;C9) om cell C8 innehåller =1/0 returneras värdet i C9, eftersom 1/0 är ett fel.

=OMFEL(C8;C9) om cell C8 innehåller =13 returneras 13, eftersom värdet i C8 inte är något fel.

## OMSAKNAS

Returns the value if the cell does not contain the #N/A (value not available) error value, or the alternative value if it does.

This function is available since LibreOffice 4.0.

#### Syntax

IFNA(Value; Alternate_value)

Värde är det värde eller uttryck som ska returneras om det inte är lika med eller resulterar i ett #SAKNAS-fel.

Alternativt_värde är det värde eller uttryck som ska returneras om uttrycket eller värdet från Värde är lika med eller resulterar i ett #SAKNAS-fel.

#### Exempel

=IFNA(D3;D4) returns the value of D3 if D3 does not result in an #N/A error, or D4 if it does.

## SAKNAS

Returnerar felvärdet #SAKNAS.

#### Syntax

SAKNAS()

#### Exempel

=SAKNAS() konverterar innehållet i cellen till #SAKNAS.

## VÄRDETYP

Returns the type of value, where 1 = number, 2 = text, 4 = Boolean value, 8 = formula, 16 = error value, 64 = array.

Om ett fel inträffar returnerar funktionen ett logiskt eller numeriskt värde.

#### Syntax

TYP(Värde)

Value is a specific value for which the data type is determined.

### Exempel (se exempeltabell ovan)

=TYP(C2) returnerar 2 som ett resultat.

=TYP(D9) returnerar 1 som ett resultat.

## ÄREJTEXT

Testar om cellen innehåller text eller tal, och returnerar FALSKT om cellen innehåller text.

Om ett fel inträffar returnerar funktionen SANT.

#### Syntax

ÄREJTEXT(Värde)

värde är ett värde eller ett uttryck för vilket du vill kontrollera om det rör sig om en text, ett tal eller ett logiskt värde.

#### Exempel

=ÄREJTEXT(D2) returnerar FALSKT om cell D2 innehåller texten abcdef.

=ÄREJTEXT(D9) returnerar SANT om cell D9 innehåller nummer 8.

## ÄRF

Returnerar SANT om värdet refererar till något annat felvärde än #SAKNAS.

Om ett fel inträffar returnerar funktionen ett logiskt eller numeriskt värde.

#### Syntax

ÄRF(Värde)

Värde är ett värde eller ett uttryck som ska testas för att avgöra om ett felvärde skilt från #SAKNAS existerar.

#### Exempel

=ÄRF(C8) där cell C8 innehåller =1/0 returnerar SANT, eftersom 1/0 är ett fel.

=ÄRF(C9) där cell C9 innehåller =SAKNAS() returnerar FALSKT, eftersom ÄRF() ignorerar felvärdet #SAKNAS.

## ÄRFEL

Returnerar SANT om värdet refererar till ett felvärde, inklusive #SAKNAS.

Om ett fel inträffar returnerar funktionen ett logiskt eller numeriskt värde.

#### Syntax

ÄRFEL(Värde)

Värde är eller hänvisar till det värde som ska testas. ÄRFEL() returnerar SANT om det finns ett fel och FALSKT om det inte finns ett fel.

#### Exempel

=ÄRFEL(C8) om cell C8 innehåller =1/0 returnerar SANT, eftersom 1/0 är ett fel.

=ÄRFEL(C9) där cell C9 innehåller =SAKNAS() returnerar SANT.

## ÄRFORMEL

Returnerar SANT om cellen är en formelcell.

Om ett fel inträffar returnerar funktionen ett logiskt eller numeriskt värde.

#### Syntax

ÄRFORMEL (referens)

Referens indikerar referensen för en cell som ska testas för om den innehåller en formel.

#### Exempel

=ÄRFORMEL(C4) returnerar FALSKT om cell C4 innehåller nummer 5.

## ÄRJÄMN

Returnerar SANT om värdet är ett jämnt heltal, och FALSKT om värdet är udda.

#### Syntax

ÄRJÄMN(Värde)

värde är värdet som ska kontrolleras.

Om Värde inte är ett heltal ignoreras alla siffror efter decimaltecknet. Tecknet för värdet ignoreras också.

#### Exempel

=ÄRJÄMN(48) returnerar SANT

=ÄRJÄMN(33) returnerar FALSKT

=ÄRJÄMN(0) returnerar SANT

=ÄRJÄMN(-2,1) returnerar SANT

=ÄRJÄMN(3,999) returnerar FALSKT

## ÄRJÄMN_ADD

Kontrollerar jämna tal. Returnerar 1 om talet delat i 2 returnerar ett heltal.

De funktioner vars namn slutar med _ADD eller _EXCEL2003 returnerar samma resultat som motsvarande funktioner i Microsoft Excel 2003 utan suffixen. Funktioner utan suffix ger resultat som är baserade på internationell standard.

#### Syntax

ÄRJÄMN_ADD(tal)

Tal är det tal som ska testas.

#### Exempel

=ÄRJÄMN_ADD(5) returnerar 0.

=ÄRJÄMN_ADD(A1) returnerar 1 om cell A1 innehåller nummer 2.

## ÄRLOGISK

Returnerar SANT om cellen innehåller ett logiskt talformat.

Om ett fel inträffar returnerar funktionen FALSKT.

#### Syntax

ÄRLOGISK(Värde)

Returnerar SANT om Värde är ett logiskt värde (SANT eller FALSKT), och returnerar i annat fall FALSKT.

#### Exempel

=ÄRLOGISK(99) returnerar FALSKT eftersom 99 är ett nummer, inte ett logiskt värde.

=ÄRLOGISK(ÄRSAKNAD(D4)) returnerar SANT oavsett innehåll i cell D4, eftersom ÄRSAKNAD () returnerar ett logiskt värde.

## ÄRREF

Kontrollerar om argumentet är en referens. Returnerar SANT om argumentet är en referens, returnerar i annat fall FALSKT. Om funktionen ges en referens kontrollerar inte funktionen det refererade värdet.

Om ett fel inträffar returnerar funktionen ett logiskt eller numeriskt värde.

#### Syntax

ÄRREF(Värde)

Värde är det värde som ska testas.

#### Exempel

=ÄRREF(C5) returnerar resultatet SANT eftersom C5 är en giltig referens.

=ÄRREF("abcdef") returnerar alltid FALSKT eftersom en text aldrig kan vara en referens.

=ÄRREF(4) returnerar FALSKT.

=ÄRREF(INDIREKT("A6")) returnerar SANT, eftersom INDIREKT är en funktion som returnerar en referens.

=ÄRREF(ADRESS(1; 1; 2;"Tabell2")) returnerar FALSKT, eftersom ADRESS är en funktion som returnerar en text även om den ser ut som en referens.

## ÄRSAKNAD

Returnerar SANT om alla celler innehåller felvärdet #SAKNAS (värdet finns inte).

Om ett fel inträffar returnerar funktionen FALSKT.

#### Syntax

ÄRSAKNAD(Värde)

värde är värdet eller ett uttryck som ska kontrolleras.

#### Exempel

=ÄRSAKNAD(D3) returnerar FALSKT som ett resultat.

## ÄRTAL

Returnerar SANT om värdet refererar till ett tal.

Om ett fel inträffar returnerar funktionen ett logiskt eller numeriskt värde.

#### Syntax

ÄRTAL(Värde)

Värde är ett uttryck som ska testas för att avgöra om det är tal eller text.

#### Exempel

=ÄRTAL(C3) returnerar SANT om cell C3 innehåller nummer 4.

=ÄRTAL(C2) returnerar FALSKT om cell C2 innehåller texten abcdef.

## ÄRTEXT

Returnerar SANT om cellinnehållet refererar till text.

Om ett fel inträffar returnerar funktionen FALSKT.

#### Syntax

ÄRTEXT(Värde)

värde är ett värde, ett tal, ett logiskt värde eller ett felvärde för vilket kontrolleras om det är text eller tal.

#### Exempel

=ÄRTEXT(D9) returnerar SANT om cell D9 innehåller texten abcdef.

=ÄRTEXT(C3) returnerar FALSKT om cell C3 innehåller nummer 3.

## ÄRTOM

Returnerar SANT om referensen till en cell är tom. Du kan använda den här funktionen för att avgöra om innehållet i en cell är tomt. En cell som innehåller en formel är inte tom.

Om ett fel inträffar returnerar funktionen ett logiskt eller numeriskt värde.

#### Syntax

ÄRTOM(Värde)

Värde är det innehåll som ska undersökas.

#### Exempel

=ÄRTOM(D2) returnerar FALSKT som ett resultat.

## ÄRUDDA

Returnerar SANT om värdet är udda, och FALSKT om värdet är jämnt.

#### Syntax

ÄRUDDA(värde)

värde är värdet som ska kontrolleras.

Om Värde inte är ett heltal ignoreras alla siffror efter decimaltecknet. Tecknet för värdet ignoreras också.

#### Exempel

=ÄRUDDA(33) returnerar SANT

=ÄRUDDA(48) returnerar FALSKT

=ÄRUDDA(3,999) returnerar SANT

=ÄRUDDA(-3,1) returnerar SANT

## ÄRUDDA_ADD

Returnerar SANT (1) om talet inte är jämnt delbart med 2.

De funktioner vars namn slutar med _ADD eller _EXCEL2003 returnerar samma resultat som motsvarande funktioner i Microsoft Excel 2003 utan suffixen. Funktioner utan suffix ger resultat som är baserade på internationell standard.

#### Syntax

ÄRUDDA_ADD(Tal)

Tal är det tal som ska testas.

#### Exempel

=ÄRUDDA_ADD(5) returnerar 1.

Närliggande ämnen

Functions by Category